Berekening van Pi

1e methode | 2e methode ][  Pi volgens Archimedes | Andere benaderingen | DK & Maple

1e methode
Onderstaande benadering van de waarde van p is gebaseerd op de recursieve betrekkingen tussen de zijde a van een ingeschreven (regelmatige) n-hoek en de zijde b van de bijbehorende omgeschreven (regelmatige) n-hoek van een cirkel.
De bedoelde recursieve betrekkingen zijn:
   b' = 2ab / (a + b)
   a' = Ö(ab')
waarin b' en a' de zijden zijn van de (bijbehorende) 2n-hoek.
Zie voor afleiding van deze formules paragraaf 3 op de pagina "Pi volgens Archimedes".
De uitgangssituatie (met b₀ en a₀) is dezelfde als die van Archimedes: een regelmatige 6-hoek met straal 1.

De berekening is uitgevoerd met Maple V, Release 4, waarbij gestart wordt met de halve omtrek van de gebruikte veelhoeken, opdat de waarde van p daaruit direct volgt.

> restart:
> a0 := 3;         # halve omtrek ingeschreven 6-hoek
> b0 := 2*sqrt(3); # halve omtrek omgeschreven 6-hoek

a0:=3
b0:=2Ö3

> archim := proc(n)
>   global a0, b0;
>   local an, bn, i;
>   # 1e benadering:
>   bn := evalf( (2 * a0 * b0) / (a0 + b0) );
>   an := evalf( sqrt(a0 * bn) );
>   # volgende benaderingen:
>   for i from 1 to n do
>     bn := (2 * an * bn) / (an + bn);
>     an := sqrt(an * bn);
>   od;
>   print (an, bn);
> end:

>for j from 0 to 3 do archim(j) od; # benaderingen (*)

3.105828542, 3.215390310
3.132628614, 3.159659942
3.139350204, 3.146086216
3.141031952, 3.142714600

> evalf(3+10/71);
> evalf(3+1/7);
> evalf(Pi);

3.140845070
3.142857143
3.141592654

(*)
De opvolgende benaderingen betreffen de 12-, 24-, 48- en 96-hoek.
Eerst bij een 96-hoek worden dus 2 significante decimalen in de ontwikkeling van p gevonden.

Opmerking
Bovenstaande berekeningsmethode staat ook bekend onder de naam Borchardt-Pfaff algorithme.
[einde Opmerking]

2e methode (snellere convergentie)
We kunnen snellere convergenttie bereiken indien we gebruikmaken van de eigenschap, dat het harmonisch gemiddelde van twee getallen kleiner is dan het meetkundig gemiddelde (zie hiervoor Hulpstelling 2 op de pagina "Pi volgens Archimedes")
We kunnen dan scherpere grenzen vaststellen via de formules
   A = 3ab / (2b+a)
   B = ³Ö(a²b)
Hierbij nemen a en b dezelfde waarden aan als in de 1e methode.
Zie paragraaf 4 (Snellere convergentie) op de pagina "Pi volgens Archimedes" voor een afleiding van de formules voor A en B.

De berekening is hieronder weer uitgevoerd met Maple V, Release 4, waarbij ook nu gestart wordt met de halve omtrek van de gebruikte veelhoeken om direct de waarde van p te krijgen.

> restart:
> a0:=3;
> b0:=2*sqrt(3);

a0:=3
b0:=2Ö3

> archim2:=proc(n)
>   global a0, b0;
>   local an, bn, a2, b2, i;
>   # berekening startwaarden voor a2=A en b2=B
>   a2 := evalf( (3*a0*b0)/(2*b0+a0) ); 
>   b2 := evalf( (b0*a0^2)^(1/3) );
>   # 1e benadering:
>   bn := evalf(2*a0*b0/(a0+b0));
>   an := evalf(sqrt(a0*bn));
>   # volgende benaderingen:
>   for i from 1 to n do
>     a2 := (3*an*bn)/(2*bn+an); 
>     b2:=(bn*an^2)^(1/3);
>     bn := 2*an*bn/(an+bn); # tbv de volgende waarden 
>     an := sqrt(an*bn);     #   van a2=A en B2=B 
>   od;
>   print (a2, b2);
> end:

> for j from 0 to 1 do archim2(j) od; # benaderingen (*)

3.140237344, 3.147345190
3.141509994, 3.141927919

> evalf(Pi);

3.14159265358979

(*)
De opeenvolgende benaderingen betreffen een 12- en een 24-hoek.
Bij deze methode worden dus al bij een 12-hoek 2 significante cijfers in de ontwikkeling van p gevonden!

Terug Top

[pi_1.htm] laatste wijziging op: 14-10-1999